7b7cda67a1
* Update Debian runtime files Add mantic as a supported Ubuntu release and move buster/kinetic to unsupported. Add syntax highlighting for deb822sources filetype. Add debsources ftplugin to set relevant comment options. Move common version information to shared/debversions.vim Closes #11934 Co-authored-by: Heinrich Schuchardt <heinrich.schuchardt@canonical.com> Co-authored-by: James Addison <jay@jp-hosting.net> Co-authored-by: Viktor Szépe <viktor@szepe.net> Signed-off-by: James McCoy <jamessan@jamessan.com> * Add myself as codeowner for Debian-related runtime files Signed-off-by: James McCoy <jamessan@jamessan.com> --------- Signed-off-by: James McCoy <jamessan@jamessan.com> Co-authored-by: Heinrich Schuchardt <heinrich.schuchardt@canonical.com> Co-authored-by: James Addison <jay@jp-hosting.net> Co-authored-by: Viktor Szépe <viktor@szepe.net> Signed-off-by: Christian Brabandt <cb@256bit.org>
63 lines
2.8 KiB
VimL
63 lines
2.8 KiB
VimL
" Vim syntax file
|
|
" Language: Debian changelog files
|
|
" Maintainer: Debian Vim Maintainers
|
|
" Former Maintainers: Gerfried Fuchs <alfie@ist.org>
|
|
" Wichert Akkerman <wakkerma@debian.org>
|
|
" Last Change: 2023 Oct 11
|
|
" URL: https://salsa.debian.org/vim-team/vim-debian/blob/main/syntax/debchangelog.vim
|
|
|
|
" Standard syntax initialization
|
|
if exists('b:current_syntax')
|
|
finish
|
|
endif
|
|
|
|
" Case doesn't matter for us
|
|
syn case ignore
|
|
|
|
let s:urgency='urgency=\(low\|medium\|high\|emergency\|critical\)\( [^[:space:],][^,]*\)\='
|
|
let s:binNMU='binary-only=yes'
|
|
|
|
" Include Debian versioning information
|
|
runtime! syntax/shared/debversions.vim
|
|
|
|
exe 'syn match debchangelogTarget contained "\%( \%('.join(g:debSharedSupportedVersions, '\|').'\)\>[-[:alnum:]]*\)\+"'
|
|
exe 'syn match debchangelogUnsupportedTarget contained "\%( \%('.join(g:debSharedUnsupportedVersions, '\|').'\)\>[-[:alnum:]]*\)\+"'
|
|
|
|
unlet g:debSharedSupportedVersions
|
|
unlet g:debSharedUnsupportedVersions
|
|
|
|
" Define some common expressions we can use later on
|
|
syn match debchangelogName contained "^[[:alnum:]][[:alnum:].+-]\+ "
|
|
exe 'syn match debchangelogFirstKV contained "; \('.s:urgency.'\|'.s:binNMU.'\)"'
|
|
exe 'syn match debchangelogOtherKV contained ", \('.s:urgency.'\|'.s:binNMU.'\)"'
|
|
syn match debchangelogUnreleased contained / UNRELEASED/
|
|
syn match debchangelogVersion contained "(.\{-})"
|
|
syn match debchangelogCloses contained "closes:\_s*\(bug\)\=#\=\_s\=\d\+\(,\_s*\(bug\)\=#\=\_s\=\d\+\)*"
|
|
syn match debchangelogLP contained "\clp:\s\+#\d\+\(,\s*#\d\+\)*"
|
|
syn match debchangelogEmail contained "[_=[:alnum:].+-]\+@[[:alnum:]./\-]\+"
|
|
syn match debchangelogEmail contained "<.\{-}>"
|
|
|
|
" Define the entries that make up the changelog
|
|
syn region debchangelogHeader start="^[^ ]" end="$" contains=debchangelogName,debchangelogFirstKV,debchangelogOtherKV,debchangelogTarget,debchangelogUnsupportedTarget,debchangelogUnreleased,debchangelogVersion,debchangelogBinNMU oneline
|
|
syn region debchangelogFooter start="^ [^ ]" end="$" contains=debchangelogEmail oneline
|
|
syn region debchangelogEntry start="^ " end="$" contains=debchangelogCloses,debchangelogLP oneline
|
|
|
|
" Associate our matches and regions with pretty colours
|
|
hi def link debchangelogHeader Error
|
|
hi def link debchangelogFooter Identifier
|
|
hi def link debchangelogEntry Normal
|
|
hi def link debchangelogCloses Statement
|
|
hi def link debchangelogLP Statement
|
|
hi def link debchangelogFirstKV Identifier
|
|
hi def link debchangelogOtherKV Identifier
|
|
hi def link debchangelogName Comment
|
|
hi def link debchangelogVersion Identifier
|
|
hi def link debchangelogUnreleased WarningMsg
|
|
hi def link debchangelogEmail Special
|
|
hi def link debchangelogTarget Identifier
|
|
hi def link debchangelogUnsupportedTarget Identifier
|
|
|
|
let b:current_syntax = 'debchangelog'
|
|
|
|
" vim: ts=8 sw=2
|