_debug "Sourcing tcshrc.system.common"

set uname=`uname`
set uname_a=`uname -a`
set uname_p=`uname -p`
set uname_m=`uname -m`

_debug "Setting uname -i tracker, based upon OS."

switch( ${CSHENV_SYSTEM} )
	case Cygwin:
	case Darwin:
	case Linux
		set uname_i
	breaksw

	default:
		#FALLTHROUGH

	case FreeBSD:
	case NetBSD:
		set uname_i="`uname -i`"
	breaksw
endsw

_debug "Setting CSHENV_BASESYSTEM..."
setenv CSHENV_BASESYSTEM "${uname}"

_debug "Setting CSHENV_FULLSYSTEM..."
setenv CSHENV_FULLSYSTEM "${uname_a}"
_debug "Done setting CSHENV_FULLSYSTEM..."

switch ( ${CSHENV_SYSTEM} )

	case Cygwin:
		_debug "Using a Cygwin system..."

		#Cygwin is like Linux, so we just...

		#FALLTHROUGH

	case Linux:
		_debug "Using a Linux-like system (GLIBC, probably)..."

		setenv CSHENV_CPU "${uname_m}"
		setenv CSHENV_MACH "${uname_p}"

		switch( CSHENV_CPU )
			case m68k:
				_debug "Running on a m68k based CPU, tweaks for system."
				
				setenv CSHENV_ARCH ${uname_p}
			breaksw

			case armv71:
				_debug "Running on an arm based CPU, tweaks for system."
				setenv CSHENV_ARCH arm
			breaksw

			default:
				setenv CSHENV_ARCH ${uname_i}
			breaksw
		endsw

	breaksw

	case Darwin:
		_debug "Using a Darwin/MacosX system..."

		setenv CSHENV_CPU ${uname_p}
		setenv CSHENV_MACH ${uname_m}

		#TODO: Fix this for intel vs. ppc check.
		setenv CSHENV_ARCH ppc
	breaksw

	case FreeBSD:
		_debug "Using a FreeBSD system..."

		setenv CSHENV_CPU ${uname_p}
		setenv CSHENV_MACH ${uname_m}
		setenv CSHENV_ARCH ${uname_p}
	breaksw

	default:
		setenv CSHENV_CPU ${uname_p}
		setenv CSHENV_MACH ${uname_m}
		setenv CSHENV_ARCH ${uname_i}
	breaksw
endsw

_debug "Detecting hostname hacks needed."

switch( ${CSHENV_SYSTEM} )

	#Broken or Non-BSD like hostname commands:
	case Cygwin:
	case SunOS:
		_debug "SYSV hostname hack."

		setenv CSHENV_HOSTNAME `hostname | tr "[:upper:]" "[:lower:]"`
	breaksw

	#Linux may be different, yet still
	case Linux:
		_debug "BSD-like hostname hack."

		setenv CSHENV_HOSTNAME `hostname | tr "[:upper:]" "[:lower:]"`
	breaksw

	#BSD like hostnames, and non-broken ones.
	default:
		_debug "BSD-like hostname hack."

		setenv CSHENV_HOSTNAME `hostname -s| tr "[:upper:]" "[:lower:]"`
	breaksw
endsw

_debug "Hostname detected as ${CSHENV_HOSTNAME}..."

if( $?CSHENV_VIRTUAL_HOSTNAME ) then
	setenv CSHENV_HOSTNAME ${CSHENV_VIRTUAL_HOSTNAME}
	_debug "Hostname overriden as ${CSHENV_HOSTNAME}..."
endif


_debug "Done sourcing tcshrc.system.common"

###########################
# vim: ft=tcsh
###########################